1С. Программное переопределение связей параметров выбора

Задача

Необходимо организовать программное переопределить связи параметров выбора по определенному событию

Решение

Для наглядности создадим новую конфигурацию со следующими справочниками:

1. «Контрагенты»;
2. «Договоры контрагентов». Подчинен справочнику «Контрагенты»;
3. «Соглашения». У реквизита «Договор контрагента» установлены параметры связей выбора по реквизитам «Владелец», «Параметр 1» и «Параметр 2».

При такой реализации в соглашении будут доступны договоры указанного контрагента с определенными параметрами.

В качестве события для переопределения связей параметров выбора будем использовать значение реквизита «Позволить выбирать любой договор контрагента». Если признак будет установлен, то позволим выбирать любой договор указанного контрагента.

Собственно код формы элемента справочника «Соглашения» и изображения результата

#Область ОбработчикиСобытийФормы

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	ПереопределитьСвязиПараметровВыбора();
КонецПроцедуры

#КонецОбласти

#Область ОбрабочикиСобытийЭлементовФормы

&НаКлиенте
Процедура ПозволитьВыбиратьЛюбойДоговорКонтрагентаПриИзменении(Элемент)
	ПереопределитьСвязиПараметровВыбора();
КонецПроцедуры

#КонецОбласти

#Область ПрограммныйИнтефейс

&НаСервере
Процедура ПереопределитьСвязиПараметровВыбора()
	
    НовыйМассив = Новый Массив();
    НовыйМассив.Добавить(Новый СвязьПараметраВыбора("Отбор.Владелец", "Объект.Контрагент"));
	
    Если Не Объект.ПозволитьВыбиратьЛюбойДоговорКонтрагента Тогда 
        НовыйМассив.Добавить(Новый СвязьПараметраВыбора("Отбор.Параметр1", "Объект.Параметр1"));
        НовыйМассив.Добавить(Новый СвязьПараметраВыбора("Отбор.Параметр2", "Объект.Параметр2"));
    КонецЕсли;	
	
    НовыеСвязи = Новый ФиксированныйМассив(НовыйМассив);
	
    Элементы.ДоговорКонтрагента.СвязиПараметровВыбора = НовыеСвязи;
	
КонецПроцедуры // ПереопределитьСвязиПараметровВыбора()

#КонецОбласти